novacoin-qt.pro

   1 TEMPLATE = app
   2 TARGET = novacoin-qt
   3 VERSION = 0.7.5
   4 INCLUDEPATH += src src/json src/qt
   5 DEFINES += QT_GUI BOOST_THREAD_USE_LIB BOOST_SPIRIT_THREADSAFE
   6 CONFIG += no_include_pwd
   7 CONFIG += thread
   8
   9 # for boost 1.37, add -mt to the boost libraries
  10 # use: qmake BOOST_LIB_SUFFIX=-mt
  11 # for boost thread win32 with _win32 sufix
  12 # use: BOOST_THREAD_LIB_SUFFIX=_win32-...
  13 # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  14
  15 # Dependency library locations can be customized with:
  16 #    BOOST_INCLUDE_PATH, BOOST_LIB_PATH, BDB_INCLUDE_PATH,
  17 #    BDB_LIB_PATH, OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  18
  19 OBJECTS_DIR = build
  20 MOC_DIR = build
  21 UI_DIR = build
  22
  23 # use: qmake "RELEASE=1"
  24 contains(RELEASE, 1) {
  25     # Mac: compile for maximum compatibility (10.5, 32-bit)
  26     macx:QMAKE_CXXFLAGS += -mmacosx-version-min=10.5 -arch x86_64 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  27
  28     !windows:!macx {
  29         # Linux: static link
  30         LIBS += -Wl,-Bstatic
  31     }
  32 }
  33
  34 !win32 {
  35 # for extra security against potential buffer overflows: enable GCCs Stack Smashing Protection
  36 QMAKE_CXXFLAGS *= -fstack-protector-all --param ssp-buffer-size=1
  37 QMAKE_LFLAGS *= -fstack-protector-all --param ssp-buffer-size=1
  38 # We need to exclude this for Windows cross compile with MinGW 4.2.x, as it will result in a non-working executable!
  39 # This can be enabled for Windows, when we switch to MinGW >= 4.4.x.
  40 }
  41 # for extra security on Windows: enable ASLR and DEP via GCC linker flags
  42 win32:QMAKE_LFLAGS *= -Wl,--dynamicbase -Wl,--nxcompat
  43 win32:QMAKE_LFLAGS += -static-libgcc -static-libstdc++
  44
  45 # use: qmake "USE_QRCODE=1"
  46 # libqrencode (http://fukuchi.org/works/qrencode/index.en.html) must be installed for support
  47 contains(USE_QRCODE, 1) {
  48     message(Building with QRCode support)
  49     DEFINES += USE_QRCODE
  50     LIBS += -lqrencode
  51 }
  52
  53 # use: qmake "USE_UPNP=1" ( enabled by default; default)
  54 #  or: qmake "USE_UPNP=0" (disabled by default)
  55 #  or: qmake "USE_UPNP=-" (not supported)
  56 # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  57 contains(USE_UPNP, -) {
  58     message(Building without UPNP support)
  59 } else {
  60     message(Building with UPNP support)
  61     count(USE_UPNP, 0) {
  62         USE_UPNP=1
  63     }
  64     DEFINES += USE_UPNP=$$USE_UPNP STATICLIB
  65     INCLUDEPATH += $$MINIUPNPC_INCLUDE_PATH
  66     LIBS += $$join(MINIUPNPC_LIB_PATH,,-L,) -lminiupnpc
  67     win32:LIBS += -liphlpapi
  68 }
  69
  70 # use: qmake "USE_DBUS=1"
  71 contains(USE_DBUS, 1) {
  72     message(Building with DBUS (Freedesktop notifications) support)
  73     DEFINES += USE_DBUS
  74     QT += dbus
  75 }
  76
  77 # use: qmake "USE_IPV6=1" ( enabled by default; default)
  78 #  or: qmake "USE_IPV6=0" (disabled by default)
  79 #  or: qmake "USE_IPV6=-" (not supported)
  80 contains(USE_IPV6, -) {
  81     message(Building without IPv6 support)
  82 } else {
  83     count(USE_IPV6, 0) {
  84         USE_IPV6=1
  85     }
  86     DEFINES += USE_IPV6=$$USE_IPV6
  87 }
  88
  89 contains(BITCOIN_NEED_QT_PLUGINS, 1) {
  90     DEFINES += BITCOIN_NEED_QT_PLUGINS
  91     QTPLUGIN += qcncodecs qjpcodecs qtwcodecs qkrcodecs qtaccessiblewidgets
  92 }
  93
  94 contains(USE_LEVELDB, -) {
  95     message(Building without LevelDB)
  96     SOURCES += src/txdb-bdb.cpp
  97 } else {
  98     message(Building with LevelDB)
  99     DEFINES += USE_LEVELDB
 100
 101     INCLUDEPATH += src/leveldb/include src/leveldb/helpers
 102     LIBS += $$PWD/src/leveldb/libleveldb.a $$PWD/src/leveldb/libmemenv.a
 103     SOURCES += src/txdb-leveldb.cpp
 104     !win32 {
 105         # we use QMAKE_CXXFLAGS_RELEASE even without RELEASE=1 because we use RELEASE to indicate linking preferences not -O preferences
 106         genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a
 107     } else {
 108         # make an educated guess about what the ranlib command is called
 109         isEmpty(QMAKE_RANLIB) {
 110             QMAKE_RANLIB = $$replace(QMAKE_STRIP, strip, ranlib)
 111         }
 112         LIBS += -lshlwapi
 113         genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX TARGET_OS=OS_WINDOWS_CROSSCOMPILE $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libleveldb.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libmemenv.a
 114     }
 115     genleveldb.target = $$PWD/src/leveldb/libleveldb.a
 116     genleveldb.depends = FORCE
 117     PRE_TARGETDEPS += $$PWD/src/leveldb/libleveldb.a
 118     QMAKE_EXTRA_TARGETS += genleveldb
 119     # Gross ugly hack that depends on qmake internals, unfortunately there is no other way to do it.
 120     QMAKE_CLEAN += $$PWD/src/leveldb/libleveldb.a; cd $$PWD/src/leveldb ; $(MAKE) clean
 121 }
 122
 123 # regenerate src/build.h
 124 !windows|contains(USE_BUILD_INFO, 1) {
 125     genbuild.depends = FORCE
 126     genbuild.commands = cd $$PWD; /bin/sh share/genbuild.sh $$OUT_PWD/build/build.h
 127     genbuild.target = $$OUT_PWD/build/build.h
 128     PRE_TARGETDEPS += $$OUT_PWD/build/build.h
 129     QMAKE_EXTRA_TARGETS += genbuild
 130     DEFINES += HAVE_BUILD_INFO
 131 }
 132
 133 contains(USE_O3, 1) {
 134     message(Building O3 optimization flag)
 135     QMAKE_CXXFLAGS_RELEASE -= -O2
 136     QMAKE_CFLAGS_RELEASE -= -O2
 137     QMAKE_CXXFLAGS += -O3
 138     QMAKE_CFLAGS += -O3
 139 }
 140
 141 QMAKE_CXXFLAGS += -msse2
 142 QMAKE_CFLAGS += -msse2
 143 QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter -Wstack-protector
 144
 145 # Input
 146 DEPENDPATH += src src/json src/qt
 147 HEADERS += src/qt/bitcoingui.h \
 148     src/qt/transactiontablemodel.h \
 149     src/qt/addresstablemodel.h \
 150     src/qt/optionsdialog.h \
 151     src/qt/sendcoinsdialog.h \
 152     src/qt/addressbookpage.h \
 153     src/qt/signverifymessagedialog.h \
 154     src/qt/aboutdialog.h \
 155     src/qt/editaddressdialog.h \
 156     src/qt/bitcoinaddressvalidator.h \
 157     src/alert.h \
 158     src/addrman.h \
 159     src/base58.h \
 160     src/bignum.h \
 161     src/checkpoints.h \
 162     src/compat.h \
 163     src/sync.h \
 164     src/util.h \
 165     src/uint256.h \
 166     src/kernel.h \
 167     src/scrypt.h \
 168     src/pbkdf2.h \
 169     src/serialize.h \
 170     src/strlcpy.h \
 171     src/main.h \
 172     src/miner.h \
 173     src/net.h \
 174     src/key.h \
 175     src/db.h \
 176     src/txdb.h \
 177     src/walletdb.h \
 178     src/script.h \
 179     src/init.h \
 180     src/irc.h \
 181     src/mruset.h \
 182     src/json/json_spirit_writer_template.h \
 183     src/json/json_spirit_writer.h \
 184     src/json/json_spirit_value.h \
 185     src/json/json_spirit_utils.h \
 186     src/json/json_spirit_stream_reader.h \
 187     src/json/json_spirit_reader_template.h \
 188     src/json/json_spirit_reader.h \
 189     src/json/json_spirit_error_position.h \
 190     src/json/json_spirit.h \
 191     src/qt/clientmodel.h \
 192     src/qt/guiutil.h \
 193     src/qt/transactionrecord.h \
 194     src/qt/guiconstants.h \
 195     src/qt/optionsmodel.h \
 196     src/qt/monitoreddatamapper.h \
 197     src/qt/transactiondesc.h \
 198     src/qt/transactiondescdialog.h \
 199     src/qt/bitcoinamountfield.h \
 200     src/wallet.h \
 201     src/keystore.h \
 202     src/qt/transactionfilterproxy.h \
 203     src/qt/transactionview.h \
 204     src/qt/walletmodel.h \
 205     src/bitcoinrpc.h \
 206     src/qt/overviewpage.h \
 207     src/qt/csvmodelwriter.h \
 208     src/crypter.h \
 209     src/qt/sendcoinsentry.h \
 210     src/qt/qvalidatedlineedit.h \
 211     src/qt/bitcoinunits.h \
 212     src/qt/qvaluecombobox.h \
 213     src/qt/askpassphrasedialog.h \
 214     src/protocol.h \
 215     src/qt/notificator.h \
 216     src/qt/qtipcserver.h \
 217     src/allocators.h \
 218     src/ui_interface.h \
 219     src/qt/rpcconsole.h \
 220     src/version.h \
 221     src/netbase.h \
 222     src/clientversion.h
 223
 224 SOURCES += src/qt/bitcoin.cpp src/qt/bitcoingui.cpp \
 225     src/qt/transactiontablemodel.cpp \
 226     src/qt/addresstablemodel.cpp \
 227     src/qt/optionsdialog.cpp \
 228     src/qt/sendcoinsdialog.cpp \
 229     src/qt/addressbookpage.cpp \
 230     src/qt/signverifymessagedialog.cpp \
 231     src/qt/aboutdialog.cpp \
 232     src/qt/editaddressdialog.cpp \
 233     src/qt/bitcoinaddressvalidator.cpp \
 234     src/alert.cpp \
 235     src/version.cpp \
 236     src/sync.cpp \
 237     src/util.cpp \
 238     src/netbase.cpp \
 239     src/key.cpp \
 240     src/script.cpp \
 241     src/main.cpp \
 242     src/miner.cpp \
 243     src/init.cpp \
 244     src/net.cpp \
 245     src/irc.cpp \
 246     src/checkpoints.cpp \
 247     src/addrman.cpp \
 248     src/db.cpp \
 249     src/walletdb.cpp \
 250     src/qt/clientmodel.cpp \
 251     src/qt/guiutil.cpp \
 252     src/qt/transactionrecord.cpp \
 253     src/qt/optionsmodel.cpp \
 254     src/qt/monitoreddatamapper.cpp \
 255     src/qt/transactiondesc.cpp \
 256     src/qt/transactiondescdialog.cpp \
 257     src/qt/bitcoinstrings.cpp \
 258     src/qt/bitcoinamountfield.cpp \
 259     src/wallet.cpp \
 260     src/keystore.cpp \
 261     src/qt/transactionfilterproxy.cpp \
 262     src/qt/transactionview.cpp \
 263     src/qt/walletmodel.cpp \
 264     src/bitcoinrpc.cpp \
 265     src/rpcdump.cpp \
 266     src/rpcnet.cpp \
 267     src/rpcmining.cpp \
 268     src/rpcwallet.cpp \
 269     src/rpcblockchain.cpp \
 270     src/rpcrawtransaction.cpp \
 271     src/qt/overviewpage.cpp \
 272     src/qt/csvmodelwriter.cpp \
 273     src/crypter.cpp \
 274     src/qt/sendcoinsentry.cpp \
 275     src/qt/qvalidatedlineedit.cpp \
 276     src/qt/bitcoinunits.cpp \
 277     src/qt/qvaluecombobox.cpp \
 278     src/qt/askpassphrasedialog.cpp \
 279     src/protocol.cpp \
 280     src/qt/notificator.cpp \
 281     src/qt/qtipcserver.cpp \
 282     src/qt/rpcconsole.cpp \
 283     src/noui.cpp \
 284     src/kernel.cpp \
 285     src/scrypt-x86.S \
 286     src/scrypt-x86_64.S \
 287     src/scrypt.cpp \
 288     src/pbkdf2.cpp
 289
 290 RESOURCES += \
 291     src/qt/bitcoin.qrc
 292
 293 FORMS += \
 294     src/qt/forms/sendcoinsdialog.ui \
 295     src/qt/forms/addressbookpage.ui \
 296     src/qt/forms/signverifymessagedialog.ui \
 297     src/qt/forms/aboutdialog.ui \
 298     src/qt/forms/editaddressdialog.ui \
 299     src/qt/forms/transactiondescdialog.ui \
 300     src/qt/forms/overviewpage.ui \
 301     src/qt/forms/sendcoinsentry.ui \
 302     src/qt/forms/askpassphrasedialog.ui \
 303     src/qt/forms/rpcconsole.ui \
 304     src/qt/forms/optionsdialog.ui
 305
 306 contains(USE_QRCODE, 1) {
 307 HEADERS += src/qt/qrcodedialog.h
 308 SOURCES += src/qt/qrcodedialog.cpp
 309 FORMS += src/qt/forms/qrcodedialog.ui
 310 }
 311
 312 contains(BITCOIN_QT_TEST, 1) {
 313 SOURCES += src/qt/test/test_main.cpp \
 314     src/qt/test/uritests.cpp
 315 HEADERS += src/qt/test/uritests.h
 316 DEPENDPATH += src/qt/test
 317 QT += testlib
 318 TARGET = novacoin-qt_test
 319 DEFINES += BITCOIN_QT_TEST
 320 }
 321
 322 CODECFORTR = UTF-8
 323
 324 # for lrelease/lupdate
 325 # also add new translations to src/qt/bitcoin.qrc under translations/
 326 TRANSLATIONS = $$files(src/qt/locale/bitcoin_*.ts)
 327
 328 isEmpty(QMAKE_LRELEASE) {
 329     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
 330     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 331 }
 332 isEmpty(QM_DIR):QM_DIR = $$PWD/src/qt/locale
 333 # automatically build translations, so they can be included in resource file
 334 TSQM.name = lrelease ${QMAKE_FILE_IN}
 335 TSQM.input = TRANSLATIONS
 336 TSQM.output = $$QM_DIR/${QMAKE_FILE_BASE}.qm
 337 TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
 338 TSQM.CONFIG = no_link
 339 QMAKE_EXTRA_COMPILERS += TSQM
 340
 341 # "Other files" to show in Qt Creator
 342 OTHER_FILES += \
 343     doc/*.rst doc/*.txt doc/README README.md res/bitcoin-qt.rc src/test/*.cpp src/test/*.h src/qt/test/*.cpp src/qt/test/*.h
 344
 345 # platform specific defaults, if not overridden on command line
 346 isEmpty(BOOST_LIB_SUFFIX) {
 347     macx:BOOST_LIB_SUFFIX = -mt
 348     windows:BOOST_LIB_SUFFIX = -mgw44-mt-1_53
 349 }
 350
 351 isEmpty(BOOST_THREAD_LIB_SUFFIX) {
 352     BOOST_THREAD_LIB_SUFFIX = $$BOOST_LIB_SUFFIX
 353 }
 354
 355 isEmpty(BDB_LIB_PATH) {
 356     macx:BDB_LIB_PATH = /opt/local/lib/db48
 357 }
 358
 359 isEmpty(BDB_LIB_SUFFIX) {
 360     macx:BDB_LIB_SUFFIX = -4.8
 361 }
 362
 363 isEmpty(BDB_INCLUDE_PATH) {
 364     macx:BDB_INCLUDE_PATH = /opt/local/include/db48
 365 }
 366
 367 isEmpty(BOOST_LIB_PATH) {
 368     macx:BOOST_LIB_PATH = /opt/local/lib
 369 }
 370
 371 isEmpty(BOOST_INCLUDE_PATH) {
 372     macx:BOOST_INCLUDE_PATH = /opt/local/include
 373 }
 374
 375 windows:DEFINES += WIN32
 376 windows:RC_FILE = src/qt/res/bitcoin-qt.rc
 377
 378 windows:!contains(MINGW_THREAD_BUGFIX, 0) {
 379     # At least qmake's win32-g++-cross profile is missing the -lmingwthrd
 380     # thread-safety flag. GCC has -mthreads to enable this, but it doesn't
 381     # work with static linking. -lmingwthrd must come BEFORE -lmingw, so
 382     # it is prepended to QMAKE_LIBS_QT_ENTRY.
 383     # It can be turned off with MINGW_THREAD_BUGFIX=0, just in case it causes
 384     # any problems on some untested qmake profile now or in the future.
 385     DEFINES += _MT BOOST_THREAD_PROVIDES_GENERIC_SHARED_MUTEX_ON_WIN
 386     QMAKE_LIBS_QT_ENTRY = -lmingwthrd $$QMAKE_LIBS_QT_ENTRY
 387 }
 388
 389 !windows:!macx {
 390     DEFINES += LINUX
 391     LIBS += -lrt
 392 }
 393
 394 macx:HEADERS += src/qt/macdockiconhandler.h
 395 macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm
 396 macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit
 397 macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0
 398 macx:ICON = src/qt/res/icons/bitcoin.icns
 399 macx:TARGET = "NovaCoin-Qt"
 400 macx:QMAKE_CFLAGS_THREAD += -pthread
 401 macx:QMAKE_LFLAGS_THREAD += -pthread
 402 macx:QMAKE_CXXFLAGS_THREAD += -pthread
 403
 404 # Set libraries and includes at end, to use platform-defined defaults if not overridden
 405 INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH $$QRENCODE_INCLUDE_PATH
 406 LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,) $$join(QRENCODE_LIB_PATH,,-L,)
 407 LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
 408 # -lgdi32 has to happen after -lcrypto (see  #681)
 409 windows:LIBS += -lws2_32 -lshlwapi -lmswsock -lole32 -loleaut32 -luuid -lgdi32
 410 LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_THREAD_LIB_SUFFIX
 411 windows:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
 412
 413 contains(RELEASE, 1) {
 414     !windows:!macx {
 415         # Linux: turn dynamic linking back on for c/c++ runtime libraries
 416         LIBS += -Wl,-Bdynamic
 417     }
 418 }
 419
 420 system($$QMAKE_LRELEASE -silent $$_PRO_FILE_)