src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.1)
   2
   3 ##
   4 ## mkdir build && cd build
   5 ##
   6 ## cmake -DBerkeleyDB_ROOT:STRING=/opt/homebrew/Cellar/berkeley-db@4/4.8.30 -DUSE_LEVELDB=1 ..
   7 ## cmake -DUSE_LEVELDB=1 ..
   8 ##
   9
  10 project(novacoind VERSION 0.5.9 LANGUAGES C CXX)
  11
  12 # Enforce sizeof(size_t) == 8 by default
  13 if (NOT ALLOW_32BIT AND NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  14     message(FATAL_ERROR "Only 64-bit processors (x86_64, AArch64) are supported")
  15 endif ()
  16
  17 # Force generic scrypt on 32 bit platforms
  18 if (NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  19     set(USE_GENERIC_SCRYPT True)
  20 endif()
  21
  22 find_program(CCACHE_FOUND ccache)
  23 if(CCACHE_FOUND)
  24     set(CMAKE_C_COMPILER_LAUNCHER ccache)
  25     set(CMAKE_CXX_COMPILER_LAUNCHER ccache)
  26 endif(CCACHE_FOUND)
  27
  28 if (NOT MSVC)
  29 set (CMAKE_C_FLAGS "-flto -O3 -fPIC -Wno-deprecated -fstack-protector-all -Wstack-protector -D_FORTIFY_SOURCE=2")
  30 set (CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-parameter -fexceptions -frtti")
  31 else()
  32 set(CMAKE_C_FLAGS "/O2")
  33 set(CMAKE_CXX_FLAGS "/O2")
  34 endif()
  35
  36 set(CMAKE_CXX_EXTENSIONS OFF)
  37
  38 set(Boost_USE_STATIC_LIBS   ON)
  39 find_package(Boost REQUIRED COMPONENTS atomic chrono filesystem program_options system thread)
  40 set(OPENSSL_USE_STATIC_LIBS ON)
  41 find_package(OpenSSL REQUIRED)
  42 add_subdirectory(additional/IXWebSocket)
  43
  44 # Set default root path for berkeley db
  45 if (NOT BerkeleyDB_ROOT)
  46 set(BerkeleyDB_ROOT /usr)
  47 endif()
  48
  49 # Set default include path for berkeley db
  50 if (NOT BerkeleyDB_INC)
  51 set(BerkeleyDB_INC ${BerkeleyDB_ROOT}/include)
  52 endif()
  53
  54 if (NOT EXISTS ${BerkeleyDB_INC}/db_cxx.h)
  55     message(FATAL_ERROR "Unable to find db_cxx.h header file in ${BerkeleyDB_INC} directory. Try to specify either include directory path via BerkeleyDB_INC or berkeley db root path via BerkeleyDB_ROOT variable.")
  56 endif()
  57
  58 # Set default library path for berkeley db
  59 if (NOT BerkeleyDB_LIBS)
  60 set(BerkeleyDB_LIBS ${BerkeleyDB_ROOT}/lib)
  61 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  62 # Workaround for linux distributions
  63 set(BerkeleyDB_LIBS ${BerkeleyDB_LIBS}/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  64 endif()
  65 endif()
  66
  67 # Set default library name for berkeley db
  68 if (NOT BerkeleyDB_LIB_name)
  69 set(BerkeleyDB_LIB_name libdb_cxx)
  70 endif()
  71
  72 set(generic_sources
  73     ${CMAKE_CURRENT_SOURCE_DIR}/addrman.cpp
  74     ${CMAKE_CURRENT_SOURCE_DIR}/alert.cpp
  75     ${CMAKE_CURRENT_SOURCE_DIR}/base58.cpp
  76     ${CMAKE_CURRENT_SOURCE_DIR}/bitcoinrpc.cpp
  77     ${CMAKE_CURRENT_SOURCE_DIR}/checkpoints.cpp
  78     ${CMAKE_CURRENT_SOURCE_DIR}/crypter.cpp
  79     ${CMAKE_CURRENT_SOURCE_DIR}/db.cpp
  80     ${CMAKE_CURRENT_SOURCE_DIR}/init.cpp
  81     ${CMAKE_CURRENT_SOURCE_DIR}/ipcollector.cpp
  82     ${CMAKE_CURRENT_SOURCE_DIR}/irc.cpp
  83     ${CMAKE_CURRENT_SOURCE_DIR}/kernel.cpp
  84     ${CMAKE_CURRENT_SOURCE_DIR}/kernel_worker.cpp
  85     ${CMAKE_CURRENT_SOURCE_DIR}/kernelrecord.cpp
  86     ${CMAKE_CURRENT_SOURCE_DIR}/key.cpp
  87     ${CMAKE_CURRENT_SOURCE_DIR}/keystore.cpp
  88     ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
  89     ${CMAKE_CURRENT_SOURCE_DIR}/miner.cpp
  90     ${CMAKE_CURRENT_SOURCE_DIR}/net.cpp
  91     ${CMAKE_CURRENT_SOURCE_DIR}/netbase.cpp
  92     ${CMAKE_CURRENT_SOURCE_DIR}/noui.cpp
  93     ${CMAKE_CURRENT_SOURCE_DIR}/ntp.cpp
  94     ${CMAKE_CURRENT_SOURCE_DIR}/protocol.cpp
  95     ${CMAKE_CURRENT_SOURCE_DIR}/rpcblockchain.cpp
  96     ${CMAKE_CURRENT_SOURCE_DIR}/rpcdump.cpp
  97     ${CMAKE_CURRENT_SOURCE_DIR}/rpcmining.cpp
  98     ${CMAKE_CURRENT_SOURCE_DIR}/rpcnet.cpp
  99     ${CMAKE_CURRENT_SOURCE_DIR}/rpcrawtransaction.cpp
 100     ${CMAKE_CURRENT_SOURCE_DIR}/rpcwallet.cpp
 101     ${CMAKE_CURRENT_SOURCE_DIR}/script.cpp
 102     ${CMAKE_CURRENT_SOURCE_DIR}/stun.cpp
 103     ${CMAKE_CURRENT_SOURCE_DIR}/sync.cpp
 104     ${CMAKE_CURRENT_SOURCE_DIR}/util.cpp
 105     ${CMAKE_CURRENT_SOURCE_DIR}/version.cpp
 106     ${CMAKE_CURRENT_SOURCE_DIR}/wallet.cpp
 107     ${CMAKE_CURRENT_SOURCE_DIR}/walletdb.cpp
 108 )
 109
 110 list(APPEND ALL_SOURCES ${generic_sources})
 111 list(APPEND ALL_LIBRARIES ${Boost_LIBRARIES} ixwebsocket OpenSSL::Crypto)
 112
 113 # Windows-specific libraries
 114 if (WIN32)
 115    list(APPEND ALL_LIBRARIES kernel32 user32 gdi32 comdlg32 winspool winmm shell32 comctl32 ole32 oleaut32 uuid rpcrt4 advapi32 ws2_32 mswsock shlwapi)
 116 endif()
 117
 118 # Some systems need rt library
 119 if (NOT WIN32 AND NOT APPLE)
 120     list(APPEND ALL_LIBRARIES rt)
 121 endif()
 122
 123 # Try various libdb library file extensions
 124 foreach(ext a so dylib lib)
 125 if (EXISTS ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 126     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 127     set (BDB_FOUND True)
 128     break()
 129 endif()
 130 endforeach()
 131
 132 if (NOT BDB_FOUND)
 133     message(FATAL_ERROR "Unable to find ${BerkeleyDB_LIB_name} library in ${BerkeleyDB_LIBS} directory. Try to specify either library path via BerkeleyDB_LIBS or berkeley db root path via BerkeleyDB_ROOT variable. You can also use BerkeleyDB_LIB_name variable to provide alternative file name search for.")
 134 endif()
 135
 136 if(USE_LEVELDB)
 137     # Disable useless targets
 138     option(LEVELDB_BUILD_TESTS "Build LevelDB's unit tests" OFF)
 139     option(LEVELDB_BUILD_BENCHMARKS "Build LevelDB's benchmarks" OFF)
 140     option(LEVELDB_INSTALL "Install LevelDB's header and library" OFF)
 141
 142     add_subdirectory(additional/leveldb)
 143     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-leveldb.cpp)
 144     list(APPEND ALL_LIBRARIES leveldb)
 145     list(APPEND ALL_DEFINITIONS USE_LEVELDB)
 146 else()
 147     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-bdb.cpp)
 148 endif()
 149
 150 if (NOT USE_GENERIC_SCRYPT)
 151     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/intrin/scrypt-intrin.cpp )
 152     list(APPEND ALL_DEFINITIONS USE_INTRIN)
 153 else()
 154     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/generic/scrypt-generic.cpp )
 155 endif()
 156
 157 # Generate build info header
 158 execute_process (
 159     COMMAND sh -c "${CMAKE_CURRENT_SOURCE_DIR}/../share/genbuild.sh ${CMAKE_CURRENT_SOURCE_DIR}/build.h"
 160     OUTPUT_VARIABLE outVar
 161 )
 162 list(APPEND ALL_DEFINITIONS HAVE_BUILD_INFO USE_IPV6)
 163
 164 add_executable(novacoind ${ALL_SOURCES})
 165 target_include_directories(novacoind PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/json ${BerkeleyDB_INC} ${CMAKE_CURRENT_SOURCE_DIR}/additional/sse2neon ${CMAKE_CURRENT_SOURCE_DIR}/additional/leveldb/helpers ${Boost_INCLUDE_DIRS})
 166 target_link_libraries(novacoind ${ALL_LIBRARIES})
 167
 168 target_compile_features(novacoind PUBLIC cxx_std_17)
 169 set_property(TARGET novacoind PROPERTY CXX_STANDARD 17)
 170 set_property(TARGET novacoind PROPERTY CXX_STANDARD_REQUIRED TRUE)
 171 set_property(TARGET novacoind PROPERTY COMPILE_DEFINITIONS ${ALL_DEFINITIONS})
 172 set_property(TARGET novacoind PROPERTY CMAKE_WARN_DEPRECATED FALSE)