src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.1)
   2
   3 ##
   4 ## mkdir build && cd build
   5 ##
   6 ## cmake -DBerkeleyDB_ROOT:STRING=/opt/homebrew/Cellar/berkeley-db@4/4.8.30 -DUSE_LEVELDB=1 ..
   7 ## cmake -DUSE_LEVELDB=1 ..
   8 ##
   9
  10 project(novacoind VERSION 0.5.9 LANGUAGES C CXX)
  11
  12 # Enforce sizeof(size_t) == 8 by default
  13 if (NOT ALLOW_32BIT AND NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  14     message(FATAL_ERROR "Only 64-bit processors (x86_64, AArch64) are supported")
  15 endif ()
  16
  17 # Force generic scrypt on 32 bit platforms
  18 if (NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  19     set(USE_GENERIC_SCRYPT True)
  20 endif()
  21
  22 find_program(CCACHE_FOUND ccache)
  23 if(CCACHE_FOUND)
  24     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  25     set(CMAKE_C_COMPILER_LAUNCHER ccache)
  26     set(CMAKE_CXX_COMPILER_LAUNCHER ccache)
  27 endif(CCACHE_FOUND)
  28
  29 set (CMAKE_C_FLAGS "-flto -O3 -fPIC -Wno-deprecated -fstack-protector-all -Wstack-protector -D_FORTIFY_SOURCE=2")
  30 set (CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -fexceptions -frtti")
  31 set(CMAKE_CXX_EXTENSIONS OFF)
  32
  33 set(Boost_USE_STATIC_LIBS   ON)
  34 find_package(Boost REQUIRED COMPONENTS atomic chrono filesystem program_options system thread)
  35 set(OPENSSL_USE_STATIC_LIBS ON)
  36 find_package(OpenSSL REQUIRED)
  37 add_subdirectory(additional/IXWebSocket)
  38
  39 # Set default root path for berkeley db
  40 if (NOT BerkeleyDB_ROOT)
  41 set(BerkeleyDB_ROOT /usr)
  42 endif()
  43
  44 # Set default include path for berkeley db
  45 if (NOT BerkeleyDB_INC)
  46 set(BerkeleyDB_INC ${BerkeleyDB_ROOT}/include)
  47 endif()
  48
  49 if (NOT EXISTS ${BerkeleyDB_INC}/db_cxx.h)
  50     message(FATAL_ERROR "Unable to find db_cxx.h header file in ${BerkeleyDB_INC} directory. Try to specify either include directory path via BerkeleyDB_INC or berkeley db root path via BerkeleyDB_ROOT variable.")
  51 endif()
  52
  53 # Set default library path for berkeley db
  54 if (NOT BerkeleyDB_LIBS)
  55 set(BerkeleyDB_LIBS ${BerkeleyDB_ROOT}/lib)
  56 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  57 # Workaround for linux distributions
  58 set(BerkeleyDB_LIBS ${BerkeleyDB_LIBS}/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  59 endif()
  60 endif()
  61
  62 # Set default library name for berkeley db
  63 if (NOT BerkeleyDB_LIB_name)
  64 set(BerkeleyDB_LIB_name libdb_cxx)
  65 endif()
  66
  67 set(generic_sources
  68     ${CMAKE_CURRENT_SOURCE_DIR}/addrman.cpp
  69     ${CMAKE_CURRENT_SOURCE_DIR}/alert.cpp
  70     ${CMAKE_CURRENT_SOURCE_DIR}/base58.cpp
  71     ${CMAKE_CURRENT_SOURCE_DIR}/bitcoinrpc.cpp
  72     ${CMAKE_CURRENT_SOURCE_DIR}/checkpoints.cpp
  73     ${CMAKE_CURRENT_SOURCE_DIR}/crypter.cpp
  74     ${CMAKE_CURRENT_SOURCE_DIR}/db.cpp
  75     ${CMAKE_CURRENT_SOURCE_DIR}/init.cpp
  76     ${CMAKE_CURRENT_SOURCE_DIR}/ipcollector.cpp
  77     ${CMAKE_CURRENT_SOURCE_DIR}/irc.cpp
  78     ${CMAKE_CURRENT_SOURCE_DIR}/kernel.cpp
  79     ${CMAKE_CURRENT_SOURCE_DIR}/kernel_worker.cpp
  80     ${CMAKE_CURRENT_SOURCE_DIR}/kernelrecord.cpp
  81     ${CMAKE_CURRENT_SOURCE_DIR}/key.cpp
  82     ${CMAKE_CURRENT_SOURCE_DIR}/keystore.cpp
  83     ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
  84     ${CMAKE_CURRENT_SOURCE_DIR}/miner.cpp
  85     ${CMAKE_CURRENT_SOURCE_DIR}/net.cpp
  86     ${CMAKE_CURRENT_SOURCE_DIR}/netbase.cpp
  87     ${CMAKE_CURRENT_SOURCE_DIR}/noui.cpp
  88     ${CMAKE_CURRENT_SOURCE_DIR}/ntp.cpp
  89     ${CMAKE_CURRENT_SOURCE_DIR}/protocol.cpp
  90     ${CMAKE_CURRENT_SOURCE_DIR}/rpcblockchain.cpp
  91     ${CMAKE_CURRENT_SOURCE_DIR}/rpcdump.cpp
  92     ${CMAKE_CURRENT_SOURCE_DIR}/rpcmining.cpp
  93     ${CMAKE_CURRENT_SOURCE_DIR}/rpcnet.cpp
  94     ${CMAKE_CURRENT_SOURCE_DIR}/rpcrawtransaction.cpp
  95     ${CMAKE_CURRENT_SOURCE_DIR}/rpcwallet.cpp
  96     ${CMAKE_CURRENT_SOURCE_DIR}/script.cpp
  97     ${CMAKE_CURRENT_SOURCE_DIR}/stun.cpp
  98     ${CMAKE_CURRENT_SOURCE_DIR}/sync.cpp
  99     ${CMAKE_CURRENT_SOURCE_DIR}/util.cpp
 100     ${CMAKE_CURRENT_SOURCE_DIR}/version.cpp
 101     ${CMAKE_CURRENT_SOURCE_DIR}/wallet.cpp
 102     ${CMAKE_CURRENT_SOURCE_DIR}/walletdb.cpp
 103 )
 104
 105 list(APPEND ALL_SOURCES ${generic_sources})
 106 list(APPEND ALL_LIBRARIES ${Boost_LIBRARIES} ixwebsocket OpenSSL::Crypto)
 107
 108 # Windows-specific libraries
 109 if (WIN32)
 110    list(APPEND ALL_LIBRARIES kernel32 user32 gdi32 comdlg32 winspool winmm shell32 comctl32 ole32 oleaut32 uuid rpcrt4 advapi32 ws2_32 mswsock shlwapi)
 111 endif()
 112
 113 # Some systems need rt library
 114 if (NOT WIN32 AND NOT APPLE)
 115     list(APPEND ALL_LIBRARIES rt)
 116 endif()
 117
 118 # Try various libdb library file extensions
 119 foreach(ext a so dylib lib)
 120 if (EXISTS ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 121     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 122     set (BDB_FOUND True)
 123     break()
 124 endif()
 125 endforeach()
 126
 127 if (NOT BDB_FOUND)
 128     message(FATAL_ERROR "Unable to find ${BerkeleyDB_LIB_name} library in ${BerkeleyDB_LIBS} directory. Try to specify either library path via BerkeleyDB_LIBS or berkeley db root path via BerkeleyDB_ROOT variable. You can also use BerkeleyDB_LIB_name variable to provide alternative file name search for.")
 129 endif()
 130
 131 if(USE_LEVELDB)
 132     # Disable useless targets
 133     option(LEVELDB_BUILD_TESTS "Build LevelDB's unit tests" OFF)
 134     option(LEVELDB_BUILD_BENCHMARKS "Build LevelDB's benchmarks" OFF)
 135     option(LEVELDB_INSTALL "Install LevelDB's header and library" OFF)
 136
 137     add_subdirectory(additional/leveldb)
 138     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-leveldb.cpp)
 139     list(APPEND ALL_LIBRARIES leveldb)
 140     list(APPEND ALL_DEFINITIONS USE_LEVELDB)
 141 else()
 142     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-bdb.cpp)
 143 endif()
 144
 145 if (NOT USE_GENERIC_SCRYPT)
 146     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/intrin/scrypt-intrin.cpp )
 147     list(APPEND ALL_DEFINITIONS USE_INTRIN)
 148 else()
 149     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/generic/scrypt-generic.cpp )
 150 endif()
 151
 152 # Generate build info header
 153 execute_process (
 154     COMMAND sh -c "${CMAKE_CURRENT_SOURCE_DIR}/../share/genbuild.sh ${CMAKE_CURRENT_SOURCE_DIR}/build.h"
 155     OUTPUT_VARIABLE outVar
 156 )
 157 list(APPEND ALL_DEFINITIONS HAVE_BUILD_INFO USE_IPV6)
 158
 159 add_executable(novacoind ${ALL_SOURCES})
 160 target_include_directories(novacoind PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/json ${BerkeleyDB_INC} ${CMAKE_CURRENT_SOURCE_DIR}/additional/sse2neon ${CMAKE_CURRENT_SOURCE_DIR}/additional/leveldb/helpers ${Boost_INCLUDE_DIRS})
 161 target_link_libraries(novacoind ${ALL_LIBRARIES})
 162
 163 target_compile_features(novacoind PUBLIC cxx_std_17)
 164 set_property(TARGET novacoind PROPERTY CXX_STANDARD 17)
 165 set_property(TARGET novacoind PROPERTY CXX_STANDARD_REQUIRED TRUE)
 166 set_property(TARGET novacoind PROPERTY COMPILE_DEFINITIONS ${ALL_DEFINITIONS})
 167 set_property(TARGET novacoind PROPERTY CMAKE_WARN_DEPRECATED FALSE)