src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.5)
   2
   3 ##
   4 ## mkdir build && cd build
   5 ##
   6 ## cmake -DBerkeleyDB_ROOT:STRING=/opt/homebrew/Cellar/berkeley-db@4/4.8.30 ..
   7 ## cmake ..
   8 ##
   9
  10 project(novacoind VERSION 0.5.9 LANGUAGES C CXX)
  11
  12 # Enforce sizeof(size_t) == 8 by default
  13 if (NOT ALLOW_32BIT AND NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  14     message(FATAL_ERROR "Only 64-bit processors (x86_64, AArch64) are supported")
  15 endif ()
  16
  17 # Force generic scrypt on 32 bit platforms
  18 if (NOT CMAKE_SIZEOF_VOID_P MATCHES "8")
  19     set(USE_GENERIC_SCRYPT True)
  20 endif()
  21
  22 find_program(CCACHE_FOUND ccache)
  23 if(CCACHE_FOUND)
  24     set(CMAKE_C_COMPILER_LAUNCHER ccache)
  25     set(CMAKE_CXX_COMPILER_LAUNCHER ccache)
  26 endif(CCACHE_FOUND)
  27
  28 if (NOT MSVC)
  29 if (NOT WIN32)
  30 set(FPIC "-fPIC")
  31 endif()
  32 set (CMAKE_C_FLAGS "-flto=auto -O3 ${FPIC} -Wno-deprecated -Wno-deprecated-declarations -fstack-protector-all")
  33 set (CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-parameter -fexceptions -frtti")
  34 else()
  35 set(CMAKE_C_FLAGS "/O2")
  36 set(CMAKE_CXX_FLAGS "/O2 /GR /EHsc")
  37 endif()
  38
  39 set(CMAKE_CXX_EXTENSIONS OFF)
  40
  41 set(Boost_USE_STATIC_LIBS   ON)
  42 if(WIN32)
  43 set(Boost_USE_STATIC_RUNTIME ON)
  44 endif()
  45 find_package(Boost REQUIRED COMPONENTS atomic chrono filesystem program_options system thread)
  46
  47 set(OPENSSL_USE_STATIC_LIBS ON)
  48 find_package(OpenSSL)
  49 if (NOT OpenSSL_FOUND)
  50 set(OPENSSL_USE_STATIC_LIBS OFF)
  51 find_package(OpenSSL REQUIRED)
  52 endif()
  53
  54 add_subdirectory(additional/IXWebSocket)
  55
  56 # Set default root path for berkeley db
  57 if (NOT BerkeleyDB_ROOT)
  58 set(BerkeleyDB_ROOT /usr)
  59 endif()
  60
  61 # Set default include path for berkeley db
  62 if (NOT BerkeleyDB_INC)
  63 set(BerkeleyDB_INC ${BerkeleyDB_ROOT}/include)
  64 endif()
  65
  66 if (NOT EXISTS ${BerkeleyDB_INC}/db_cxx.h)
  67     message(FATAL_ERROR "Unable to find db_cxx.h header file in ${BerkeleyDB_INC} directory. Try to specify either include directory path via BerkeleyDB_INC or berkeley db root path via BerkeleyDB_ROOT variable.")
  68 endif()
  69
  70 # Set default library path for berkeley db
  71 if (NOT BerkeleyDB_LIBS)
  72 set(BerkeleyDB_LIBS ${BerkeleyDB_ROOT}/lib)
  73 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  74 # Workaround for linux distributions
  75     execute_process (
  76         COMMAND bash -c "test -d ${BerkeleyDB_LIBS}/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu && echo -n 'present' || echo -n 'absent'"
  77         OUTPUT_VARIABLE dirPresent
  78     )
  79     if(dirPresent STREQUAL "present")
  80         set(BerkeleyDB_LIBS ${BerkeleyDB_LIBS}/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  81     endif()
  82 endif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  83 endif()
  84
  85 # Set default library name for berkeley db
  86 if (NOT BerkeleyDB_LIB_name)
  87 set(BerkeleyDB_LIB_name libdb_cxx)
  88 endif()
  89
  90 set(generic_sources
  91     ${CMAKE_CURRENT_SOURCE_DIR}/addrman.cpp
  92     ${CMAKE_CURRENT_SOURCE_DIR}/alert.cpp
  93     ${CMAKE_CURRENT_SOURCE_DIR}/allocators.cpp
  94     ${CMAKE_CURRENT_SOURCE_DIR}/base58.cpp
  95     ${CMAKE_CURRENT_SOURCE_DIR}/bignum.cpp
  96     ${CMAKE_CURRENT_SOURCE_DIR}/bitcoinrpc.cpp
  97     ${CMAKE_CURRENT_SOURCE_DIR}/checkpoints.cpp
  98     ${CMAKE_CURRENT_SOURCE_DIR}/coincontrol.cpp
  99     ${CMAKE_CURRENT_SOURCE_DIR}/crypter.cpp
 100     ${CMAKE_CURRENT_SOURCE_DIR}/db.cpp
 101     ${CMAKE_CURRENT_SOURCE_DIR}/init.cpp
 102     ${CMAKE_CURRENT_SOURCE_DIR}/ipcollector.cpp
 103     ${CMAKE_CURRENT_SOURCE_DIR}/irc.cpp
 104     ${CMAKE_CURRENT_SOURCE_DIR}/kernel.cpp
 105     ${CMAKE_CURRENT_SOURCE_DIR}/kernel_worker.cpp
 106     ${CMAKE_CURRENT_SOURCE_DIR}/kernelrecord.cpp
 107     ${CMAKE_CURRENT_SOURCE_DIR}/key.cpp
 108     ${CMAKE_CURRENT_SOURCE_DIR}/keystore.cpp
 109     ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
 110     ${CMAKE_CURRENT_SOURCE_DIR}/miner.cpp
 111     ${CMAKE_CURRENT_SOURCE_DIR}/net.cpp
 112     ${CMAKE_CURRENT_SOURCE_DIR}/netbase.cpp
 113     ${CMAKE_CURRENT_SOURCE_DIR}/noui.cpp
 114     ${CMAKE_CURRENT_SOURCE_DIR}/ntp.cpp
 115     ${CMAKE_CURRENT_SOURCE_DIR}/protocol.cpp
 116     ${CMAKE_CURRENT_SOURCE_DIR}/random.cpp
 117     ${CMAKE_CURRENT_SOURCE_DIR}/rpcblockchain.cpp
 118     ${CMAKE_CURRENT_SOURCE_DIR}/rpcdump.cpp
 119     ${CMAKE_CURRENT_SOURCE_DIR}/rpcmining.cpp
 120     ${CMAKE_CURRENT_SOURCE_DIR}/rpcnet.cpp
 121     ${CMAKE_CURRENT_SOURCE_DIR}/rpcrawtransaction.cpp
 122     ${CMAKE_CURRENT_SOURCE_DIR}/rpcwallet.cpp
 123     ${CMAKE_CURRENT_SOURCE_DIR}/script.cpp
 124     ${CMAKE_CURRENT_SOURCE_DIR}/streams.cpp
 125     ${CMAKE_CURRENT_SOURCE_DIR}/stun.cpp
 126     ${CMAKE_CURRENT_SOURCE_DIR}/sync.cpp
 127     ${CMAKE_CURRENT_SOURCE_DIR}/timedata.cpp
 128     ${CMAKE_CURRENT_SOURCE_DIR}/uint256.cpp
 129     ${CMAKE_CURRENT_SOURCE_DIR}/util.cpp
 130     ${CMAKE_CURRENT_SOURCE_DIR}/version.cpp
 131     ${CMAKE_CURRENT_SOURCE_DIR}/wallet.cpp
 132     ${CMAKE_CURRENT_SOURCE_DIR}/walletdb.cpp
 133 )
 134
 135 list(APPEND ALL_SOURCES ${generic_sources})
 136 list(APPEND ALL_LIBRARIES ${Boost_LIBRARIES} ixwebsocket OpenSSL::Crypto)
 137
 138 if (WIN32)
 139     # Windows-specific libraries
 140     list(APPEND ALL_LIBRARIES kernel32 user32 gdi32 comdlg32 winspool winmm shell32 comctl32 ole32 oleaut32 uuid rpcrt4 advapi32 ws2_32 mswsock shlwapi pthread)
 141     list(APPEND ALL_DEFINITIONS WIN32)
 142
 143     # Resources
 144     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/bitcoin.rc bitcoin.rc)
 145     list(APPEND ALL_SOURCES ${CMAKE_BINARY_DIR}/bitcoin.rc)
 146 endif()
 147
 148 # Some systems need rt library
 149 if (NOT WIN32 AND NOT APPLE)
 150     list(APPEND ALL_LIBRARIES rt)
 151 endif()
 152
 153 # Try various libdb library file extensions
 154 foreach(ext a so dylib lib)
 155 if (EXISTS ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 156     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/${BerkeleyDB_LIB_name}.${ext})
 157     set (BDB_FOUND True)
 158     break()
 159 endif()
 160 endforeach()
 161
 162 if (NOT BDB_FOUND)
 163     message(FATAL_ERROR "Unable to find ${BerkeleyDB_LIB_name} library in ${BerkeleyDB_LIBS} directory. Try to specify either library path via BerkeleyDB_LIBS or berkeley db root path via BerkeleyDB_ROOT variable. You can also use BerkeleyDB_LIB_name variable to provide alternative file name search for.")
 164 endif()
 165
 166 # Disable useless targets
 167 option(LEVELDB_BUILD_TESTS "Build LevelDB's unit tests" OFF)
 168 option(LEVELDB_BUILD_BENCHMARKS "Build LevelDB's benchmarks" OFF)
 169 option(LEVELDB_INSTALL "Install LevelDB's header and library" OFF)
 170
 171 add_subdirectory(additional/leveldb)
 172 list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-leveldb.cpp)
 173 list(APPEND ALL_LIBRARIES leveldb)
 174
 175 if (NOT USE_GENERIC_SCRYPT)
 176     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/intrin/scrypt-intrin.cpp )
 177     list(APPEND ALL_DEFINITIONS USE_INTRIN)
 178 else()
 179     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/generic/scrypt-generic.cpp )
 180 endif()
 181
 182 # Generate build info header
 183 execute_process (
 184     COMMAND sh -c "${CMAKE_CURRENT_SOURCE_DIR}/../share/genbuild.sh ${CMAKE_CURRENT_SOURCE_DIR}/build.h"
 185     OUTPUT_VARIABLE outVar
 186 )
 187 list(APPEND ALL_DEFINITIONS HAVE_BUILD_INFO USE_IPV6 BOOST_SPIRIT_THREADSAFE)
 188
 189 add_executable(novacoind ${ALL_SOURCES})
 190
 191 target_precompile_headers(novacoind
 192   PRIVATE
 193     <algorithm>
 194     <cassert>
 195     <cerrno>
 196     <cinttypes>
 197     <climits>
 198     <condition_variable>
 199     <csignal>
 200     <cstdarg>
 201     <cstdint>
 202     <cstdio>
 203     <cstring>
 204     <ctime>
 205     <deque>
 206     <fstream>
 207     <functional>
 208     <iomanip>
 209     <ios>
 210     <iostream>
 211     <limits>
 212     <list>
 213     <map>
 214     <memory>
 215     <mutex>
 216     <ostream>
 217     <regex>
 218     <set>
 219     <stdexcept>
 220     <sstream>
 221     <string>
 222     <tuple>
 223     <type_traits>
 224     <variant>
 225     <vector>
 226     <utility>
 227 )
 228
 229 if (NOT MSVC)
 230 list(APPEND ALL_DEFINITIONS _FORTIFY_SOURCE=2)
 231 set(ALL_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fstack-protector-all")
 232 if (WIN32)
 233 list(APPEND ALL_LIBRARIES mingw32 ssp)
 234 set(ALL_LINKER_FLAGS "${ALL_LINKER_FLAGS} -static-libgcc -static")
 235 endif()
 236 set(CMAKE_EXE_LINKER_FLAGS ${ALL_LINKER_FLAGS} CACHE INTERNAL "")
 237 endif()
 238
 239 target_include_directories(novacoind PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/json ${BerkeleyDB_INC} ${CMAKE_CURRENT_SOURCE_DIR}/additional/leveldb/helpers ${Boost_INCLUDE_DIRS})
 240 target_link_libraries(novacoind ${ALL_LIBRARIES})
 241
 242 target_compile_features(novacoind PUBLIC cxx_std_17)
 243 set_property(TARGET novacoind PROPERTY CXX_STANDARD 17)
 244 set_property(TARGET novacoind PROPERTY CXX_STANDARD_REQUIRED TRUE)
 245 set_property(TARGET novacoind PROPERTY COMPILE_DEFINITIONS ${ALL_DEFINITIONS})
 246 set_property(TARGET novacoind PROPERTY CMAKE_WARN_DEPRECATED FALSE)