src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.1)
   2
   3 ##
   4 ## mkdir build && cd build
   5 ##
   6 ## cmake -DBerkeleyDB_ROOT:STRING=/opt/homebrew/Cellar/berkeley-db@4/4.8.30 ..
   7 ## cmake -DUSE_ASM=1 ..
   8 ## cmake -DUSE_SSE2 ..
   9 ## cmake -DBerkeleyDB_INC:STRING=/usr/include -DBerkeleyDB_LIBS:STRING=/usr/lib/aarch64-linux-gnu -DUSE_SSE2 -DUSE_LEVELDB ..
  10 ##
  11
  12 project(novacoind VERSION 0.5.9 LANGUAGES C CXX ASM)
  13
  14 find_program(CCACHE_FOUND ccache)
  15 if(CCACHE_FOUND)
  16     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  17     set(CMAKE_C_COMPILER_LAUNCHER ccache)
  18     set(CMAKE_CXX_COMPILER_LAUNCHER ccache)
  19 endif(CCACHE_FOUND)
  20
  21 set (CMAKE_C_FLAGS "-flto -O3 -fPIC -Wno-deprecated -fstack-protector-all -Wstack-protector -D_FORTIFY_SOURCE=2")
  22 set (CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -fexceptions -frtti")
  23
  24 set(Boost_USE_STATIC_LIBS   ON)
  25 find_package(Boost REQUIRED COMPONENTS atomic chrono filesystem program_options system thread)
  26 set(OPENSSL_USE_STATIC_LIBS ON)
  27 find_package(OpenSSL REQUIRED)
  28 add_subdirectory(additional/IXWebSocket)
  29
  30 # Set default root path for berkeley db
  31 if (NOT BerkeleyDB_ROOT)
  32 set(BerkeleyDB_ROOT /usr)
  33 endif()
  34
  35 # Set default include path for berkeley db
  36 if (NOT BerkeleyDB_INC)
  37 set(BerkeleyDB_INC ${BerkeleyDB_ROOT}/include)
  38 endif()
  39
  40 if (NOT EXISTS ${BerkeleyDB_INC}/db_cxx.h)
  41     message(FATAL_ERROR "Unable to find db_cxx.h header file in ${BerkeleyDB_INC} directory. Try to specify either include directory path via BerkeleyDB_INC or berkeley db root path via BerkeleyDB_ROOT variable.")
  42 endif()
  43
  44 # Set default library path for berkeley db
  45 if (NOT BerkeleyDB_LIBS)
  46 set(BerkeleyDB_LIBS ${BerkeleyDB_ROOT}/lib)
  47 endif()
  48
  49 set(generic_sources
  50     ${CMAKE_CURRENT_SOURCE_DIR}/addrman.cpp
  51     ${CMAKE_CURRENT_SOURCE_DIR}/alert.cpp
  52     ${CMAKE_CURRENT_SOURCE_DIR}/base58.cpp
  53     ${CMAKE_CURRENT_SOURCE_DIR}/bitcoinrpc.cpp
  54     ${CMAKE_CURRENT_SOURCE_DIR}/checkpoints.cpp
  55     ${CMAKE_CURRENT_SOURCE_DIR}/crypter.cpp
  56     ${CMAKE_CURRENT_SOURCE_DIR}/db.cpp
  57     ${CMAKE_CURRENT_SOURCE_DIR}/init.cpp
  58     ${CMAKE_CURRENT_SOURCE_DIR}/ipcollector.cpp
  59     ${CMAKE_CURRENT_SOURCE_DIR}/irc.cpp
  60     ${CMAKE_CURRENT_SOURCE_DIR}/kernel.cpp
  61     ${CMAKE_CURRENT_SOURCE_DIR}/kernel_worker.cpp
  62     ${CMAKE_CURRENT_SOURCE_DIR}/kernelrecord.cpp
  63     ${CMAKE_CURRENT_SOURCE_DIR}/key.cpp
  64     ${CMAKE_CURRENT_SOURCE_DIR}/keystore.cpp
  65     ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
  66     ${CMAKE_CURRENT_SOURCE_DIR}/miner.cpp
  67     ${CMAKE_CURRENT_SOURCE_DIR}/net.cpp
  68     ${CMAKE_CURRENT_SOURCE_DIR}/netbase.cpp
  69     ${CMAKE_CURRENT_SOURCE_DIR}/noui.cpp
  70     ${CMAKE_CURRENT_SOURCE_DIR}/ntp.cpp
  71     ${CMAKE_CURRENT_SOURCE_DIR}/protocol.cpp
  72     ${CMAKE_CURRENT_SOURCE_DIR}/rpcblockchain.cpp
  73     ${CMAKE_CURRENT_SOURCE_DIR}/rpcdump.cpp
  74     ${CMAKE_CURRENT_SOURCE_DIR}/rpcmining.cpp
  75     ${CMAKE_CURRENT_SOURCE_DIR}/rpcnet.cpp
  76     ${CMAKE_CURRENT_SOURCE_DIR}/rpcrawtransaction.cpp
  77     ${CMAKE_CURRENT_SOURCE_DIR}/rpcwallet.cpp
  78     ${CMAKE_CURRENT_SOURCE_DIR}/script.cpp
  79     ${CMAKE_CURRENT_SOURCE_DIR}/stun.cpp
  80     ${CMAKE_CURRENT_SOURCE_DIR}/sync.cpp
  81     ${CMAKE_CURRENT_SOURCE_DIR}/util.cpp
  82     ${CMAKE_CURRENT_SOURCE_DIR}/version.cpp
  83     ${CMAKE_CURRENT_SOURCE_DIR}/wallet.cpp
  84     ${CMAKE_CURRENT_SOURCE_DIR}/walletdb.cpp
  85 )
  86
  87 list(APPEND ALL_SOURCES ${generic_sources})
  88 list(APPEND ALL_LIBRARIES ${Boost_LIBRARIES} ixwebsocket OpenSSL::Crypto)
  89
  90 # Try various libdb library file extensions
  91 if (EXISTS ${BerkeleyDB_LIBS}/libdb_cxx.a)
  92     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/libdb_cxx.a)
  93 elseif(EXISTS ${BerkeleyDB_LIBS}/libdb_cxx.so)
  94     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/libdb_cxx.so)
  95 elseif(EXISTS ${BerkeleyDB_LIBS}/libdb_cxx.dylib)
  96     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/libdb_cxx.dylib)
  97 elseif(EXISTS ${BerkeleyDB_LIBS}/libdb_cxx.dll)
  98     list(APPEND ALL_LIBRARIES ${BerkeleyDB_LIBS}/libdb_cxx.dll)
  99 else()
 100    message(FATAL_ERROR "Unable to find libdb_cxx library in ${BerkeleyDB_LIBS} directory. Try to specify either library path via BerkeleyDB_LIBS or berkeley db root path via BerkeleyDB_ROOT variable.")
 101 endif()
 102
 103 if(USE_LEVELDB)
 104     # Disable useless targets
 105     option(LEVELDB_BUILD_TESTS "Build LevelDB's unit tests" OFF)
 106     option(LEVELDB_BUILD_BENCHMARKS "Build LevelDB's benchmarks" OFF)
 107     option(LEVELDB_INSTALL "Install LevelDB's header and library" OFF)
 108
 109     add_subdirectory(additional/leveldb)
 110     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-leveldb.cpp)
 111     list(APPEND ALL_LIBRARIES leveldb)
 112     list(APPEND ALL_DEFINITIONS USE_LEVELDB)
 113 else()
 114     list(APPEND ALL_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/txdb-bdb.cpp)
 115 endif()
 116
 117 if (USE_ASM)
 118     # Assembler implementation
 119     set(asm_sources
 120         ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/asm/scrypt-arm.S
 121         ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/asm/scrypt-x86.S
 122         ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/asm/scrypt-x86_64.S
 123     )
 124
 125     list(APPEND ALL_SOURCES ${generic_sources} ${asm_sources})
 126     list(APPEND ALL_DEFINITIONS USE_ASM)
 127 elseif (USE_SSE2)
 128     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/intrin/scrypt-sse2.cpp )
 129     list(APPEND ALL_DEFINITIONS USE_SSE2)
 130 else()
 131     list( APPEND ALL_SOURCES ${generic_sources} ${CMAKE_CURRENT_SOURCE_DIR}/crypto/scrypt/generic/scrypt-generic.cpp )
 132 endif()
 133
 134 # Generate build info header
 135 execute_process (
 136     COMMAND sh -c "${CMAKE_CURRENT_SOURCE_DIR}/../share/genbuild.sh ${CMAKE_CURRENT_SOURCE_DIR}/build.h"
 137     OUTPUT_VARIABLE outVar
 138 )
 139 list(APPEND ALL_DEFINITIONS HAVE_BUILD_INFO)
 140
 141 add_executable(novacoind ${ALL_SOURCES})
 142 target_include_directories(novacoind PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/json ${BerkeleyDB_INC} ${CMAKE_CURRENT_SOURCE_DIR}/additional/leveldb/helpers ${Boost_INCLUDE_DIRS})
 143 target_link_libraries(novacoind ${ALL_LIBRARIES})
 144
 145 set_property(TARGET novacoind PROPERTY CXX_STANDARD 17)
 146 set_property(TARGET novacoind PROPERTY CXX_STANDARD_REQUIRED TRUE)
 147 set_property(TARGET novacoind PROPERTY COMPILE_DEFINITIONS ${ALL_DEFINITIONS})
 148 set_property(TARGET novacoind PROPERTY CMAKE_WARN_DEPRECATED FALSE)